rem # https://docs.microsoft.com/zh-tw/windows-hardware/manufacture/desktop/configure-uefigpt-based-hard-drive-partitions
rem # DiskPart /s E:\CreatePartitions-UEFI_AnyDiskSize_PE_ACER.txt

rem == CreatePartitions-UEFI.txt ==
rem == 0. Initialize it by yourself ===2023-02-02===
rem # select disk 10
rem # clean
rem # convert gpt


rem ================================================

rem == 1. System partition =========================
create partition efi size=260
rem ## bootice fix driver letter
format quick fs=fat32 label="System"
rem remove letter="S" NoErr
assign letter="S" NoErr

rem == 2. Microsoft Reserved (MSR) partition =======
create partition msr size=16

rem == 3. Windows partition ========================
rem 209788+248005=457793
rem create partition primary size=209788
rem create partition primary size=457793
rem create partition primary size=453111
create partition primary

format quick fs=ntfs label="Windows"
rem remove letter="W" NoErr
assign letter="W" NoErr

rem ## shrink	950+17920=18870
rem shrink desired=18870
rem 1024+20480=21504
rem shrink desired=21504
rem 1024+20480+2048=23552
rem 1024+20480+20480+2048=44032
shrink desired=44032

rem === 4. Recovery tools partition ================
rem create partition primary size=950
create partition primary size=1024
format quick fs=ntfs label="Recovery"
rem "de94bba4-06d1-4d40-a16a-bfd50179d6ac" (set Recovery Flag on the partition)
set id="de94bba4-06d1-4d40-a16a-bfd50179d6ac"

rem 0x8000000000000000 (prevent assigning drive letter automatically on new machines) default 
rem 0x8000000000000001 (set as required partition by system) 
rem ## gpt attributes=0x8000000000000001

rem remove letter="R" NoErr
assign letter="R" NoErr
rem ## set id=27

rem === 5. Restore partition ================
rem create partition primary size=17920
rem create partition primary size=20480
rem create partition primary size=30720
create partition primary size=40960
format quick fs=ntfs label="Restore" 
rem remove letter="T" NoErr
assign letter="T" NoErr

rem === 6. Windows_PE partition ================
create partition primary size=2048
format quick fs=fat32 label="Windows_PE" 
rem remove letter="P" NoErr
assign letter="P" NoErr

list volume
list partition
exit